From 05a0a278fca7a8df9ab3b357f0e51056db80f85d Mon Sep 17 00:00:00 2001
From: Alexandru Croitor <alexandru.croitor@qt.io>
Date: Mon, 24 Feb 2020 12:38:55 +0100
Subject: [PATCH] CMake: Allow disabling warnings similar to CONFIG += warn_off

The QT_COMPILE_OPTIONS_WARNINGS_OFF property can be set on targets
in order to disable adding the default compiler warnings flags.

This is useful when building 3rd party library code.

Change-Id: I9f58ca4543b5ea0d2051b7f94f0042d24c4e3a16
Reviewed-by: Leander Beernaert <leander.beernaert@qt.io>
Reviewed-by: Simon Hausmann <simon.hausmann@qt.io>
---
 cmake/QtBuild.cmake         |  8 ++++++++
 cmake/QtCompilerFlags.cmake | 23 +++++++++++++++++++++--
 2 files changed, 29 insertions(+), 2 deletions(-)

diff --git a/cmake/QtBuild.cmake b/cmake/QtBuild.cmake
index 58f820416c..4cc14588d7 100644
--- a/cmake/QtBuild.cmake
+++ b/cmake/QtBuild.cmake
@@ -1423,6 +1423,14 @@ function(qt_skip_warnings_are_errors_when_repo_unclean target)
     endif()
 endfunction()
 
+function(qt_disable_warnings target)
+    get_target_property(target_type "${target}" TYPE)
+    if(target_type STREQUAL "INTERFACE_LIBRARY")
+        return()
+    endif()
+    set_target_properties("${target}" PROPERTIES QT_COMPILE_OPTIONS_DISABLE_WARNINGS ON)
+endfunction()
+
 function(qt_get_sanitized_plugin_type plugin_type out_var)
     # Used to handle some edge cases such as platforms/darwin
     string(REGEX REPLACE "[-/]" "_" plugin_type "${plugin_type}")
diff --git a/cmake/QtCompilerFlags.cmake b/cmake/QtCompilerFlags.cmake
index 35733027f5..a376ac0097 100644
--- a/cmake/QtCompilerFlags.cmake
+++ b/cmake/QtCompilerFlags.cmake
@@ -1,6 +1,25 @@
 # Set warnings. All compilers except MSVC support -Wall -Wextra
+# Allow opting out by setting a QT_COMPILE_WARNINGS_OFF property on targets. This would be the
+# equivalent of qmake's CONFIG += warn_off.
+
+set(_qt_compiler_warning_flags_on "")
+set(_qt_compiler_warning_flags_off "")
+
 if (MSVC)
-    add_compile_options(/W3)
+    list(APPEND _qt_compiler_warning_flags_on /W3)
+    list(APPEND _qt_compiler_warning_flags_off -W0)
 else()
-    add_compile_options(-Wall -Wextra)
+    list(APPEND _qt_compiler_warning_flags_on -Wall -Wextra)
+    list(APPEND _qt_compiler_warning_flags_off -w)
 endif()
+
+set(_qt_compiler_warning_flags_condition
+    "$<BOOL:$<TARGET_PROPERTY:QT_COMPILE_OPTIONS_DISABLE_WARNINGS>>")
+set(_qt_compiler_warning_flags_genex
+    "$<IF:${_qt_compiler_warning_flags_condition},${_qt_compiler_warning_flags_off},${_qt_compiler_warning_flags_on}>")
+
+# Need to replace semicolons so that the list is not wrongly expanded in the add_compile_options
+# call.
+string(REPLACE ";" "$<SEMICOLON>"
+       _qt_compiler_warning_flags_genex "${_qt_compiler_warning_flags_genex}")
+add_compile_options(${_qt_compiler_warning_flags_genex})